Функция _GDIPlus_StringFormatSetAlign

         Описание функции

_GDIPlus_StringFormatSetAlign

Устанавливает выравнивание текста для объекта String Format

#include <GDIPlus.au3>
_GDIPlus_StringFormatSetAlign($hStringFormat,$iFlag)

Параметры

$hStringFormat Объект String Format, который выравнивает
$iFlag Флаг выравнивания может быть одним из следующих значений:
    0 - Текст выравнивается по левому краю
    1 - Текст центрируется
    2 - Текст выравнивается по правому краю

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GDIPlus_StringFormatCreate

См. также

Искать GdipSetStringFormatAlign в библиотеке MSDN

Пример

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Local $hWnd = GUICreate("GDI+ Example", 400, 300)
GUISetState()

_GDIPlus_Startup()
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hWnd)
_GDIPlus_GraphicsClear($hGraphics)

Local $hBrush = _GDIPlus_BrushCreateSolid(0xFF009900)
Local $hFamily = _GDIPlus_FontFamilyCreate("Arial")
Local $hFont = _GDIPlus_FontCreate($hFamily, 36)
Local $hLayout = _GDIPlus_RectFCreate(0, 0, 400, 300)
Local $hStringFormat = _GDIPlus_StringFormatCreate()
_GDIPlus_StringFormatSetAlign($hStringFormat, 1)
_GDIPlus_GraphicsDrawStringEx($hGraphics, "AutoIt Rocks", $hFont, $hLayout, $hStringFormat, $hBrush)

Local $msg
Do
    $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE


_GDIPlus_BrushDispose($hBrush)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_FontDispose($hFont)
_GDIPlus_StringFormatDispose($hStringFormat)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()