Функция _Date_Time_DOSDateToArray

         Описание функции

_Date_Time_DOSDateToArray

Декодирует DOS дату в массив

#include <Date.au3>
_Date_Time_DOSDateToArray($iDosDate)

Параметры

$iDosDate MS-DOS дата, упакованная следующим образом:
    Биты 0- 4 день месяца (1–31)
    Биты 5- 8 месяц (1 = январь, 2 = февраль и так далее)
    Биты 9-15 год со смещением от 1980 (для получения фактического года нужно добавить 1980)

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Месяц
        [1] - День
        [2] - Год

См. также

_Date_Time_DOSTimeToArray, _Date_Time_DOSDateTimeToArray

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $aDate

    ; Создаёт GUI
    $hGUI = GUICreate("Время", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Показывает FAT дату
    $aDate = _Date_Time_DOSDateToArray(0x3621) ; 01/01/2007
    MemoWrite("FAT дата .: " & StringFormat("%02d/%02d/%04d", $aDate[0], $aDate[1], $aDate[2]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite