Функция _Date_Time_DOSDateTimeToArray

_Date_Time_DOSDateTimeToArray

Декодирует DOS время/дату в массив

#include <Date.au3>
_Date_Time_DOSDateTimeToArray($iDosDate, $iDosTime)

Параметры

$iDosDate	MS-DOS дата, упакованная следующим образом: Биты 0- 4 день месяца (1–31) Биты 5- 8 месяц (1 = январь, 2 = февраль и так далее) Биты 9-15 год со смещением от 1980 (для получения фактического года нужно добавить 1980)
$iDosTime	MS-DOS время, упакованное следующим образом: Биты 0- 4 секунда, деленная на 2 Биты 5-10 минута (0–59) Биты 11-15 час (0–23 в 24-часовом формате)

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Месяц
        [1] - День
        [2] - Год
        [3] - Час
        [4] - Минута
        [5] - Секунда

См. также

_Date_Time_DOSDateToArray, _Date_Time_DOSTimeToArray

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $aDate

; Создаёт GUI
$hGUI = GUICreate("Время", 400, 300)
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

; Показывает FAT дату/время
$aDate = _Date_Time_DOSDateTimeToArray(0x3621, 0x944a) ; 01/01/2007 18:34:20
MemoWrite("FAT дата .: " & StringFormat("%02d/%02d/%04d", $aDate[0], $aDate[1], $aDate[2]))
MemoWrite("FAT время .: " & StringFormat("%02d:%02d:%02d", $aDate[3], $aDate[4], $aDate[5]))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite