Функция _ClipBoard_GetOpenWindow

         Описание функции

_ClipBoard_GetOpenWindow

Возвращает дескриптор окна, который в данный момент имеет открытый буфера обмена

#include <Clipboard.au3>
_ClipBoard_GetOpenWindow()

Возвращаемое значение

Успех:Возвращает дескриптор окна, имеющий открытый буфера обмена
Ошибка:Возвращает 0, если нет окон с открытым буфером обмена

Примечания

Если приложение или DLL указывает NULL в качестве дескриптора окна при вызове функции _ClipBoard_Open, то буфер обмена открывается, но не ассоциируется с окном. В этом случае функция _ClipBoard_GetOpenWindow возвращает 0.

См. также

_ClipBoard_GetOwner, _ClipBoard_Open

См. также

Искать GetOpenClipboardWindow в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI

    ; Создаёт GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Открывает буфер обмена
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

        ; Закрывает буфер обмена
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("Ошибка функции _ClipBoard_Open")
    EndIf

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Показывает статистику буфера обмена
Func ShowData($hGUI)
    MemoWrite("Дескриптор GUI ........: " & $hGUI)
    MemoWrite("Владелец буфера .......: " & _ClipBoard_GetOwner())
    MemoWrite("Окно открывшее буфер ..: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite