Функция _ClipBoard_Close

         Описание функции

_ClipBoard_Close

Закрывает буфер обмена

#include <Clipboard.au3>
_ClipBoard_Close()

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Когда окно завершило обследование или изменение буфера обмена, то закройте буфер обмена вызовом этой функции.
Это позволяет другим окнам доступ к буферу обмена. Не помещайте объект в буфер обмена после вызова этой функции.

См. также

_ClipBoard_Open

См. также

Искать CloseClipboard в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI

    ; Создаёт GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Открывает буфер обмена
    If Not _ClipBoard_Open($hGUI) Then _WinAPI_ShowError("Ошибка функции _ClipBoard_Open")

    ; Показывает количество доступных форматов буфера обмена
    MemoWrite("Количество форматов буфера ..: " & _ClipBoard_CountFormats())

    ; Очищает буфер обмена
    If Not _ClipBoard_Empty() Then _WinAPI_ShowError("_ClipBoard_Empty failed")

    ; Показывает количество доступных форматов буфера обмена
    MemoWrite("Количество форматов буфера ..: " & _ClipBoard_CountFormats())

    ; Закрывает буфер обмена
    _ClipBoard_Close()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite