Функция _ClipBoard

Функция _ClipBoard_GetData

_ClipBoard_GetData

Возвращает данные буфера обмена в указанном формате

#include <Clipboard.au3>
_ClipBoard_GetData([$iFormat = 1])

Параметры

$iFormat

[необязательный] Указывает формат буфера обмена:
    $CF_TEXT - Текстовый формат
    $CF_BITMAP - Дескриптор растрового рисунка (HBITMAP)
    $CF_METAFILEPICT - Дескриптор метафайла рисунка (METAFILEPICT)
    $CF_SYLK - Формат Символической Связи Microsoft (SYLK)
    $CF_DIF - Формат обмена данными программы Arts'
    $CF_TIFF - Формат файла тегированного изображения
    $CF_OEMTEXT - Текстовый формат, содержащий символы в OEM наборе символов
    $CF_DIB - Структура BITMAPINFO, сопровождаемая растровыми битами
    $CF_PALETTE - Дескриптор цветовой палитры
    $CF_PENDATA - Данные для пера для Pen Computing (Компьютерного пера).
    $CF_RIFF - Звуковые данные в формате RIFF
    $CF_WAVE - Звуковые данные в формате WAVE
    $CF_UNICODETEXT - Текстовый формат в юникоде
    $CF_ENHMETAFILE - Дескриптор улучшенного метафайла (HENHMETAFILE)
    $CF_HDROP - Дескриптор типа HDROP, идентифицирующий список файлов
    $CF_LOCALE - Дескриптор локального идентификатора, связанного с текстом в буфере обмена
    $CF_DIBV5 - Структура BITMAPV5HEADER, сопровождаемая растровыми цветами и растровыми битами
    $CF_OWNERDISPLAY - Собственный формат отображения данных
    $CF_DSPTEXT - Формат отображения текста, связанный с собственным форматом
    $CF_DSPBITMAP - Растровый формат отображения, связанный с собственным форматом
    $CF_DSPMETAFILEPICT - Формат отображения данных метафайла-картинки, связанного с собственным форматом
    $CF_DSPENHMETAFILE - Формат отображения улучшенного метафайла связанного с собственным форматом

Возвращаемое значение

Успех:	Возвращает текст для базовых текстовых форматов или бинарные данные для всех остальных форматов
	@extended содержит количество (#) символов для текста или количество (#) байт для бинарных данных
Ошибка:	Возвращает 0

Примечания

Эта функция выполняет все шаги, необходимые для получения данных из буфера обмена. Это проверяет, доступен ли формат данных, открывает буфер обмена, закрывает буфер обмена и возвращает данные в одном из двух форматов: строковый формат для типов данных $CF_TEXT, $CF_OEMTEXT или $CF_UNICODETEXT, или бинарный формат для любого другого типа данных. Если необходимо больше возможностей для управления над извлечением данных из буфера обмена, то используйте функцию _ClipBoard_GetDataEx.

См. также

_ClipBoard_GetDataEx, _ClipBoard_SetData, _ClipBoard_SetDataEx

Пример

#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
Local $hGUI, $btn_SetData, $btn_GetData

; Создаёт GUI
$hGUI = GUICreate("Clipboard", 600, 450)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
$btn_SetData = GUICtrlCreateButton("Вставить в буфер обмена", 120, 410, 160, 30)
$btn_GetData = GUICtrlCreateButton("Получить из буфера обмена", 320, 410, 160, 30)
GUISetState()

; Цикл выполняется, пока окно не будет закрыто
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $btn_SetData
_ClipBoard_SetData("Текст для буфера обмена")
Case $btn_GetData
GUICtrlSetData($iMemo, _ClipBoard_GetData() & @CRLF, 1)
EndSwitch
WEnd

EndFunc ;==>_Main