Функция ControlTreeView

         Описание функции

ControlTreeView

Высылает команду элементу TreeView32.

ControlTreeView ( "title", "text", controlID, "command" [, option1 [, option2 ]] )

Параметры

title Заголовок/дескриптор/класс окна. См. заголовки и текст окон (расширенные).
text Текст окна.
controlID Идентификатор элемента управления. Смотрите Элементы управления.
command Высылаемая элементу команда. Смотрите таблицу ниже.
option1 [необязательный] Дополнительный параметр необходимый для некоторых команд.
option2 [необязательный] Дополнительный параметр необходимый для некоторых команд.

Возвращаемое значение

Действие зависит от команд указанных ниже в таблице. В случае ошибки (например, неверная команда или окно/элемент не найден) устанавливается @error = 1.


"command" [, option1 [, option2 ]] Действие
"Check", "пункт" Устанавливает галочку на пункте (если пункт поддерживает это).
"Collapse", "пункт" Свернуть пункт, скрыв вложенные.
"Exists", "пункт" Возвращает 1, если пункт существует, иначе 0.
"Expand", "пункт" Развернуть пункт, отобразив вложенные.
"GetItemCount", "пункт" Возвращает количество вложенных пунктов для выбранного пункта.
"GetSelected" [, UseIndex] Возвращает название выбранного пункта в виде пути в дереве (или индекс-ссылку, если UseIndex = 1).
"GetText", "пункт" Возвращает текст пункта, указанного в виде пути или индекс-ссылки.
"IsChecked" Возвращает состояние пункта. 1:с галочкой, 0:без галочки, -1:не checkbox.
"Select", "пункт" Выбрать пункт, указанный в виде пути или индекс-ссылки.
"Uncheck", "пункт" Снять галочку с пункта (если пункт поддерживает это).


Параметр "пункт", фигурирующий в выше указанной таблице, представляет собой ссылку на конкретный пункт TreeView в виде комбинации текста и/или индексов. Начальный индекс 0. Например:


Heading1
----> H1SubItem1
----> H1SubItem2
----> H1SubItem3
----> ----> H1S1SubItem1
Heading2
Heading3


Каждый "уровень" отделяет символ |. Индексу предшествует #. Например:

ПунктПункт-ссылка
Heading2"Heading2" или "#1"
H1SubItem2"Heading1|H1SubItem2" или "#0|#1"
H1S1SubItem1"Heading1|H1SubItem3|H1S1SubItem1" или "#0|#2|#0"

Пункт-ссылка может быть смешанной, например "Heading1|#1".

Примечания

Так как AutoIt является 32-битным приложением, то некоторые команды недоступны при обращении к 64-битным приложениям, таким как Explorer, когда запущен в 64-битной Windows.

См. также

ControlCommand

Пример

#include <GUIConstantsEx.au3>
#include <TreeviewConstants.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("ControlTreeview", 212, 212)
$iTreeView_1 = GUICtrlCreateTreeView(6, 6, 200, 160, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
$hTreeView_1 = ControlGetHandle($hGUI, "", $iTreeView_1)

$iRoot = GUICtrlCreateTreeViewItem("Корневой", $iTreeView_1)
$item1 = GUICtrlCreateTreeViewItem("Пункт 1", $iRoot)
$item2 = GUICtrlCreateTreeViewItem("Пункт 2", $iRoot)
$item3 = GUICtrlCreateTreeViewItem("Пункт 3", $iRoot)
$iItem_4 = GUICtrlCreateTreeViewItem("Пункт 4", $iRoot)
GUICtrlCreateTreeViewItem("Пункт 4.1", $iItem_4)
GUICtrlCreateTreeViewItem("Пункт 4.2", $iItem_4)
GUICtrlCreateTreeViewItem("Пункт 5", $iRoot)

GUISetState(@SW_SHOW, $hGUI)

; some examples
ControlTreeView($hGUI, "", $hTreeView_1, "Expand", "Корневой")

ControlTreeView($hGUI, "", $hTreeView_1, "Exists", "Корневой|Пункт 4")
ControlTreeView($hGUI, "", $hTreeView_1, "Check", "Корневой|Пункт 4")
ControlTreeView($hGUI, "", $hTreeView_1, "Select", "Корневой|Пункт 4")
ControlTreeView($hGUI, "", $hTreeView_1, "Expand", "Корневой|Пункт 4")

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd