Функция _WIM_LoadImage

         Описание функции

_WIM_LoadImage

Загружает образ из wim-файла

#Include <wimgapi.au3>
_WIM_LoadImage ( $hWIM, $dwImageIndex )

Параметры

$hWIM Дескриптор wim-файла возвращённый функцией _WIM_CreateFile()
$dwImageIndex Индекс загружаемого образа, отсчёт от 1. Wim-файл может хранить несколько образов.

Возвращаемое значение

Успех:Возвращает открытый дескриптор объекта образа.
Ошибка:Возвращает 0 и устанавливает @error:
@error:1 - Не удалось использовать DLL файл
2 - Неизвестный тип возвращаемого значения
3 - Не найдена функция в DLL файле
4 - Не верное число параметров
В обоих случаях @extended равен _WinAPI_GetLastError()

Примечания

Вы должны вызвать функцию _WIM_SetTemporaryPath() перед вызовом функции _WIM_LoadImage(), таким образом метаданные образа могут быть извлечены и обработаны во временной папке. Используйте функцию _WIM_CloseHandle(), чтобы выгрузить образ.

См. также

_WIM_CreateFile, _WIM_CloseHandle, _WIM_SetTemporaryPath

Пример

; Homes32
; http://www.autoitscript.com/forum/topic/127075-wimgapi-udf/
#include <wimgapi.au3>

Local $hWim, $hImage, $sPath, $sWimPath

$sWimPath = FileOpenDialog('Выбрать файл-образ', @WorkingDir, 'Образ (*.wim)', 3, 'install.wim')
If @error Then Exit

$sPath = FileSelectFolder('Выбрать папку, в которую извлечь', '', 3, @WorkingDir)
If @error Then Exit

$aResult = _WIM_Startup() ; Открывает wimgapi.dll
If @error Then Exit MsgBox(0, 'Сообщение', 'Ошибка открытия wimgapi.dll')

; Открывает существующий wim-файл
$hWim = _WIM_CreateFile($sWimPath, $WIM_GENERIC_READ + $WIM_GENERIC_WRITE, $WIM_OPEN_EXISTING, $WIM_FLAG_SHARE_WRITE, $WIM_COMPRESS_LZX)
If $hWim Then
    MsgBox(0, 'Сообщение', 'Дескриптор wim-файла $hWim = ' & $hWim)
Else
    MsgBox(0, 'Сообщение', 'Ошибка создания wim-файла')
    _Exit()
EndIf
; Устанавливает временную папку
$iRes = _WIM_SetTemporaryPath($hWim, @TempDir)
If Not $iRes Then
    MsgBox(0, 'Сообщение', 'Не удалось установить временную папку')
    _Exit()
EndIf
; Загружает образ
$hImage = _WIM_LoadImage($hWim, 1)
If $hImage Then
    MsgBox(0, 'Сообщение', 'Дескриптор образа $hImage = ' & $hImage)
Else
    MsgBox(0, 'Сообщение', 'Ошибка создания образа')
    _Exit()
EndIf
$iFlag = _WIM_ApplyImage($hImage, $sPath, $WIM_FLAG_INDEX)
If $iFlag Then
    MsgBox(0, 'Сообщение', 'Удачно извлечено = ' & $iFlag)
Else
    MsgBox(0, 'Сообщение', 'Неудача _WIM_ApplyImage')
EndIf
_Exit()

Func _Exit()
    If $hImage Then _WIM_CloseHandle($hImage) ; Закрывает открытый дескриптор
    If $hWim Then _WIM_CloseHandle($hWim) ; Закрывает открытый дескриптор
    _WIM_Shutdown() ; Выгружает wimgapi.dll
    Exit
EndFunc