Функция _GDIPlus_GraphicsDrawCachedBitmap

         Описание функции

_GDIPlus_GraphicsDrawCachedBitmap

Рисует изображение хранящееся в объекте CachedBitmap

#Include <GDIP.au3>
_GDIPlus_GraphicsDrawCachedBitmap($hGraphics, $hCachedBitmap, $iX, $iY)

Параметры

$hGraphics Указатель на объект Graphics
$hCachedBitmap Указатель на объект CachedBitmap
$iX X-координата левого верхнего угла выводимого изображения
$iY Y-координата левого верхнего угла выводимого изображения

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки.

См. также

_GDIPlus_CachedBitmapCreate

Пример

#include <GDIP.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hBmp, $hBitmap, $hCachedBitmap

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    ; Создаёт GUI (нажмите ESC для выхода)
    $hGUI = GUICreate("Рисует кэшированный bitmap", @DesktopWidth/2, @DesktopHeight/2)

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ; Делает снимок левой верхней части экрана
    $hBmp = _ScreenCapture_Capture("", 0, 0, @DesktopWidth / 2, @DesktopHeight / 2, False)

    ; Создаёт объект GDI+ Bitmap из объекта GDI Bitmap
    $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBmp)

    ; Создаёт кэшированный bitmap из существующего bitmap и graphics объектов
    $hCachedBitmap = _GDIPlus_CachedBitmapCreate($hBitmap, $hGraphics)

    GUISetState()
    ; Теперь рисует кэшированный bitmap
    _GDIPlus_GraphicsDrawCachedBitmap($hGraphics, $hCachedBitmap, 0, 0)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_CachedBitmapDispose($hCachedBitmap)
    _GDIPlus_ImageDispose($hBitmap)
    _WinAPI_DeleteObject($hBmp)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc