Функция _GDIPlus_FontGetSize

         Описание функции

_GDIPlus_FontGetSize

Получает размер шрифта (обычно em-размер) объекта Font

#Include <GDIP.au3>
_GDIPlus_FontGetSize($hFont)

Параметры

$hFont Указатель на объект Font

Возвращаемое значение

Успех:Возвращает em-размер шрифта
Ошибка:Возвращает 0, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки

Примечания

Размер в единицах объекта Font

См. также

Искать GdipGetFontSize в библиотеке MSDN

Пример

#include <GDIP.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hFontFamily, $hFont, $hBrush, $tLayout

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("Размер шрифта", 300, 200, 10)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ;  Создаёт шрифт
    $hFontFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFontFamily, 24)

    ; Создаёт сплошную кисть
    $hBrush = _GDIPlus_BrushCreateSolid()

    ; Рисует строку
    $tLayout = _GDIPlus_RectFCreate(30, 30)
    _GDIPlus_GraphicsDrawStringEx($hGraphics, "Это шрифт", $hFont, $tLayout, 0, $hBrush)

    MsgBox(0, 'Сообщение', 'Размер шрифта: ' & _GDIPlus_FontGetSize($hFont))

    ; Освобождает ресурсы
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_FontFamilyDispose($hFontFamily)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc