Функция _GDIPlus_FontClone

         Описание функции

_GDIPlus_FontClone

Создаёт клон шрифта

#Include <GDIP.au3>
_GDIPlus_FontClone($hFont)

Параметры

$hFont Указатель на объект шрифта

Возвращаемое значение

Успех:Возвращает дескриптор нового клона шрифта
Ошибка:Возвращает 0, либо:
Если ошибка DllCall(), устанавливает @error и @extended возвращённые вызовом DllCall()
$GDIP_STATUS содержит не нулевое значение кода ошибки

Примечания

После завершения использования объекта вызовите _GDIPlus_FontDispose, чтобы освободить ресурсы объекта.

См. также

Пример

; Authenticity
; http://www.autoitscript.com/forum/index.php?showtopic=106021
#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
    Local $hGUI, $hGraphics, $hFontFamily, $hFont, $hFontCloned, $hBrush, $tLayout

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()

    $hGUI = GUICreate("Создаёт клон шрифта", 500, 200)
    GUISetState()

    ; Создаёт графический объект из дескриптора окна
    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    ;  Создаёт шрифт
    $hFontFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFontFamily, 24)

    ; Создаёт клон шрифта
    $hFontCloned = _GDIPlus_FontClone($hFont)

    ; Создаёт сплошную кисть
    $hBrush = _GDIPlus_BrushCreateSolid()

    ; Рисует строку
    $tLayout = _GDIPlus_RectFCreate(30, 30)
    _GDIPlus_GraphicsDrawStringEx($hGraphics, "Это клонированный шрифт", $hFontCloned, $tLayout, 0, $hBrush)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_FontFamilyDispose($hFontFamily)
    _GDIPlus_FontDispose($hFontCloned)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_GraphicsDispose($hGraphics)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc