_WinAPI_GetBkMode
Возвращает текущий режим смешивания фона для указанного контекста устройства
#include <WinAPI.au3>
_WinAPI_GetBkMode($hDC)
Параметры
| $hDC | Дескриптор контекста устройства, режим фона которого нужно получить |
Возвращаемое значение
| Успех: | Возвращает режим смешивания фона, OPAQUE (непрозрачный) или TRANSPARENT (прозрачный) |
| Ошибка: | Возвращает 0 |
Примечания
The background mix mode of a device context affects text, hatched brushes, and pen styles that are not solid lines.См. также
_WinAPI_SetBkMode, _WinAPI_DrawText, _WinAPI_CreatePen, _WinAPI_SelectObjectСм. также
Искать GetBkMode в библиотеке MSDNПример
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <FontConstants.au3>
Global $tRECT, $hFont, $hOldFont, $hDC
HotKeySet("{ESC}", "_Exit")
$tRECT = DllStructCreate($tagRect)
DllStructSetData($tRECT, "Left", 5)
DllStructSetData($tRECT, "Top", 5)
DllStructSetData($tRECT, "Right", 250)
DllStructSetData($tRECT, "Bottom", 50)
$hDC = _WinAPI_GetDC(0)
$hFont = _WinAPI_CreateFont(50, 0, 0, 0, 400, False, False, False, $DEFAULT_CHARSET, _
$OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, 'Arial')
$hOldFont = _WinAPI_SelectObject($hDC, $hFont)
_WinAPI_SetTextColor($hDC, 0x0000FF)
_WinAPI_SetBkColor($hDC, 0x000000)
MsgBox(4096, "Информация", "GetBkMode: " & _WinAPI_GetBkMode($hDC))
; Закомментируйте следующую строку, чтобы получить черный фон вместо прозрачного
_WinAPI_SetBkMode($hDC, $TRANSPARENT)
MsgBox(4096, "Информация", "GetBkMode: " & _WinAPI_GetBkMode($hDC))
While 1
_WinAPI_DrawText($hDC, "Привет мир!", $tRECT, $DT_CENTER)
Sleep(100)
WEnd
Func _Exit()
_WinAPI_SelectObject($hDC, $hOldFont)
_WinAPI_DeleteObject($hFont)
_WinAPI_ReleaseDC(0, $hDC)
_WinAPI_InvalidateRect(0, 0)
$tRECT = 0
Exit
EndFunc ;==>_Exit