Функция _WinAPI_FillRect

 ↑  ←  Описание функции

_WinAPI_FillRect

Заполняет прямоугольник, используя указанную кисть

#include <WinAPI.au3>
_WinAPI_FillRect($hDC, $ptrRect, $hBrush)

Параметры

$hDC Дескриптор контекста устройства
$ptrRect Указатель на структуру $tagRECT содержащую координаты прямоугольника, который должен быть заполнен.
$hBrush Дескриптор кисти используемой для заполнения прямоугольника

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Кисть определяет параметр $hBrush, который может быть дескриптором кисти или значение цвета.
Если указать дескриптор кисти, вызывайте _WinAPI_CreateSolidBrush().
Кроме того, вы можете получить дескриптор, одного из встроенных шаблонов кисти с помощью функции _WinAPI_GetStockObject().
Если указать значение цвета в параметре $hBrush, то оно должно быть одним из стандартных системных цветов (значение 1 должно быть добавлено к выбранному цвету)

См. также

_WinAPI_FrameRect

См. также

Искать FillRect в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
    Local $hGUI, $hBrush, $hDC
    Local $hBrush, $hDC, $hGUI, $ptrRect, $tRect

    ; Создаёт GUI
    $hGUI = GUICreate("FillRect", 400, 300)
    $hDC = _WinAPI_GetWindowDC($hGUI)
    GUISetState()

    $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
    $tRect = DllStructCreate($tagRECT)
    DllStructSetData($tRect, "Left", 20)
    DllStructSetData($tRect, "Top", 50)
    DllStructSetData($tRect, "Right", 200)
    DllStructSetData($tRect, "Bottom", 200)
    $ptrRect = DllStructGetPtr($tRect)
    _WinAPI_FillRect($hDC, $ptrRect, $hBrush)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _WinAPI_DeleteObject($hBrush)
    _WinAPI_ReleaseDC($hGUI, $hDC)

EndFunc