_SQLite_QuerySingleRow
Получает первую строку результата указанного запроса
#include <SQLite.au3>
_SQLite_QuerySingleRow($hDB, $sSQL, ByRef $aRow)
Параметры
| $hDB | Дескриптор открытой базы данных, укажите -1 для использования последней открытой базы данных |
| $sSQL |
SQL-выражение, которое будет выполнено |
| $aRow |
Вывод строки данных |
Возвращаемое значение
| Успех: | Возвращает $SQLITE_OK |
| Ошибка: | Возвращаемое значение можно сравнить с константами $SQLITE_ * |
| @error: | -1 - SQLite сообщил об ошибке (Проверьте возвращаемое значение) |
| 1 - Ошибка вызова _SQLite_Query() | |
| 2 - Вызов предотвращен безопасным режимом | |
| 3 - Ошибка вызова _SQLite_FetchData | |
| 4 - Ошибка вызова _SQLite_QueryFinalize |
См. также
_SQLite_QueryПример
#include <SQLite.au3>
#include <SQLite.dll.au3>
Local $aRow
_SQLite_Startup()
ConsoleWrite("Версия библиотеки SQLite = " & _SQLite_LibVersion() & @CRLF)
_SQLite_Open() ; открывает базу данных в памяти
_SQLite_Exec(-1, "CREATE TEMP TABLE settings (key,value);") ; создаёт таблицу
_SQLite_Exec(-1, "INSERT INTO settings (key,value) VALUES ('1','значение один');") ; вставляет значения в таблицу
_SQLite_Exec(-1, "INSERT INTO settings (key,value) VALUES ('2','значение два');")
_SQLite_Exec(-1, "INSERT INTO settings (key,value) VALUES ('3','значение три');")
_SQLite_Exec(-1, "INSERT INTO settings (key,value) VALUES ('4','значение четыре');")
; выбирает одно поле "value", одной строки из таблицы "settings", где key > 2
_SQLite_QuerySingleRow(-1, "SELECT value FROM settings WHERE key > '2';", $aRow)
MsgBox(0, "Одно из значений для key > 2:", $aRow[0])
_SQLite_Close()
_SQLite_Shutdown()