_SQLite_Query
Готовит SQLite-запрос
#include <SQLite.au3>
_SQLite_Query($hDB, $sSQL, ByRef $hQuery)
Параметры
| $hDB | Дескриптор открытой базы данных, укажите -1 для использования последней открытой базы данных |
| $sSQL |
SQL-выражение, которое будет выполнено |
| $hQuery |
Вывод дескриптора запроса |
Возвращаемое значение
| Успех: | Возвращает $SQLITE_OK |
| Ошибка: | Возвращаемое значение можно сравнить с константами $SQLITE_ * |
| @error: | -1 - SQLite сообщил об ошибке (Проверьте возвращаемое значение) |
| 1 - Ошибка вызова 'sqlite3_prepare16_v2' SQLite API | |
| 2 - Вызов предотвращен безопасным режимом |
См. также
_SQLite_FetchData, _SQLite_FetchNames, _SQLite_Exec, _SQLite_GetTable, _SQLite_GetTable2d, _SQLite_QueryFinalize, _SQLite_QueryReset, _SQLite_QuerySingleRow, _SQLite_SetTimeoutПример
#include <SQLite.au3>
#include <SQLite.dll.au3>
Local $hQuery, $aRow, $sMsg
_SQLite_Startup()
ConsoleWrite("Версия библиотеки SQLite = " & _SQLite_LibVersion() & @CRLF)
_SQLite_Open() ; открывает базу данных в памяти
_SQLite_Exec(-1, "CREATE TABLE aTest (a,b,c);") ; создает таблицу "aTest"
_SQLite_Exec(-1, "INSERT INTO aTest(a,b,c) VALUES ('c','2','мир');") ; вставляет данные
_SQLite_Exec(-1, "INSERT INTO aTest(a,b,c) VALUES ('b','3',' ');") ; вставляет данные
_SQLite_Exec(-1, "INSERT INTO aTest(a,b,c) VALUES ('a','1','Привет');") ; вставляет данные
_SQLite_Query(-1, "SELECT c FROM aTest ORDER BY a;", $hQuery) ; выполняет запрос
While _SQLite_FetchData($hQuery, $aRow) = $SQLITE_OK ; читает вывод следующей строки
$sMsg &= $aRow[0]
WEnd
_SQLite_Exec(-1, "DROP TABLE aTest;") ; удаляет таблицу "aTest"
MsgBox(0, "SQLite", "Данные, полученные при помощи запроса: " & $sMsg)
_SQLite_Close()
_SQLite_Shutdown()
; вывод:
;
; Привет мир