Функция _Net_Share_SessionGetInfo

 ↑  ←  Описание функции

_Net_Share_SessionGetInfo

Retrieves information about a session established between a server and workstation

#include <NetShare.au3>
_Net_Share_SessionGetInfo($sServer, $sClientName, $sUserName)

Параметры

$sServer String that specifies the DNS or NetBIOS name of the remote server on which the function is to
    execute. If this parameter is blank the local computer is used.
$sClientName Specifies the name of the computer session for which information is to be returned. This
    parameter cannot be blank.
$sUserName String that specifies the name of the user whose session information is to be returned. This
    parameter cannot be blank.

Возвращаемое значение

Успех:Возвращает массив следующего формата:
[0] - Name of the computer that established the session
[1] - Name of the user who established the session
[2] - Number of files, devices, and pipes opened during the session
[3] - Number of seconds the session has been active
[4] - Number of seconds the session has been idle
[5] - Specifies how the user established the session:
1 - User established session using a guest account
2 - User established session without using password encryption
[6] - Specifies the type of client that established the session
Ошибка:Устанавливает @error

Примечания

Only members of the Administrators or Server Operators local group can execute this function

См. также

_Net_Share_FileGetInfo, _Net_Share_ShareGetInfo

См. также

Искать NetSessionGetInfo в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $sServer, $aInfo

    ; Создаёт GUI
    $hGUI = GUICreate("NetShare", 400, 300)

    ; Создаёт элемент для заметок
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get server and share information
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; Get session information
    $aInfo = _Net_Share_SessionGetInfo ($sServer, @ComputerName, "Administrator")
    MemoWrite("Error ..........: " & @error)
    MemoWrite("Computer name ..: " & $aInfo[0])
    MemoWrite("User name ......: " & $aInfo[1])
    MemoWrite("Resources open .: " & $aInfo[2])
    MemoWrite("Seconds active .: " & $aInfo[3])
    MemoWrite("Seconds idle ...: " & $aInfo[4])
    MemoWrite("Connection type : " & $aInfo[5])
    MemoWrite("Client type ....: " & $aInfo[6])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite