Функция _Net_Share_FileClose

 ↑  ←  Описание функции

_Net_Share_FileClose

Forces a resource to close

#include <NetShare.au3>
_Net_Share_FileClose($sServer, $iFileID)

Параметры

$sServer Specifies the DNS or NetBIOS name of the remote server on which the function is to execute. If
    this parameter is blank, the local computer is used.
$iFileID Specifies the file identifier of the opened resource instance to close

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Only members of the Administrators or Server Operators local group can execute this function

См. также

Искать NetFileClose в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $sServer, $aInfo

    ; Создаёт GUI
    $hGUI = GUICreate("NetShare", 400, 300)

    ; Создаёт элемент для заметок
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get server and share information
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; Enumerate open files on the server
    $aInfo = _Net_Share_FileEnum ($sServer)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aInfo[0][0])

    ; Force close any file open named "Test.txt"
    For $iI = 1 To $aInfo[0][0]
        If StringInStr($aInfo[$iI][3], "Test.txt") > 0 Then
            _Net_Share_FileClose ($sServer, $aInfo[$iI][0])
            MemoWrite("Closed file")
        EndIf
    Next

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite