_GUICtrlTreeView_InsertItem
Вставляет пункт
#include <GuiTreeView.au3>
_GUICtrlTreeView_InsertItem($hWnd, $sItem_Text [, $hItem_Parent = 0 [, $hItem_After = 0 [, $iImage = -1 [, $iSelImage = -1]]]])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $sItem_Text |
Текст нового пункта. См. примечания |
| $hItem_Parent |
[необязательный] Дескриптор / Идентификатор (ID) пункта родительского пункта |
| $hItem_After |
[необязательный] Дескриптор / Идентификатор (ID) пункта / флаг пункта, после которого вставляется новый пункт |
| $iImage |
[необязательный] Индекс иконки в списке изображений, отсчёт от 0 |
| $iSelImage |
[необязательный] Индекс иконки в списке изображений, отсчёт от 0 |
Возвращаемое значение
| Успех: | Возвращает дескриптор нового пункта |
| Ошибка: | Возвращает 0 |
Примечания
Если необходимо уведомления обратного вызова (callback) укажите $sItem_Text = -1 (LPSTR_TEXTCALLBACK).Пример
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $hImage, $hStateImage
_Main()
Func _Main()
Local $hItem[10], $hChildItem[30], $iYItem = 0, $iRand, $hInsert, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
GUICreate("Вставляет пункт", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To 9
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
For $y = 1 To 3
$hChildItem[$iYItem] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $iYItem), $hItem[$x])
$iYItem += 1
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$iRand = Random(0, 9, 1)
MsgBox(4160, "Информация", StringFormat("Вставленный после индекса %d: %s", $iRand, _GUICtrlTreeView_InsertItem($hTreeView, "Вставленный пункт", 0, $hItem[$iRand])))
$iRand = Random(0, 29, 1)
$hInsert = _GUICtrlTreeView_InsertItem($hTreeView, "Вставленный пункт", _GUICtrlTreeView_GetParentHandle($hTreeView, $hChildItem[$iRand]), $hChildItem[$iRand])
_GUICtrlTreeView_SelectItem($hTreeView, $hInsert)
MsgBox(4160, "Информация", StringFormat("Вставленный после дочернего индекса %d: %s", $iRand, $hInsert))
$hInsert = _GUICtrlTreeView_InsertItem($hTreeView, "Вставленный первый дочерний пункт", _GUICtrlTreeView_GetParentHandle($hTreeView, $hChildItem[$iRand]), $TVI_FIRST)
MsgBox(4160, "Информация", StringFormat("Вставленный дочерний индекс %d первым: %s", $iRand, $hInsert))
_GUICtrlTreeView_SelectItem($hTreeView, $hInsert)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main