Функция _GUICtrlTreeView_FindItemEx

 ↑  ←  Описание функции

_GUICtrlTreeView_FindItemEx

Возвращает дескриптор пункта найденного на основе пути в дереве TreeView

#include <GuiTreeView.au3>
_GUICtrlTreeView_FindItemEx($hWnd, $sPath [, $hStart = 0])

Параметры

$hWnd Дескриптор элемента
$sPath Выбираемый путь, с разделителем по вашему выбору, смотрите Opt("GUIDataSeparatorChar")
$hStart [необязательный] Пункт, от которого начинать поиск. Если 0, то использовать корневой пункт.

Возвращаемое значение

Успех:Возвращает дескриптор первого найденного пункта, соответствующий пути в дереве TreeView
Ошибка:Возвращает 0

Примечания

Поиск не зависит регистра символов

См. также

_GUICtrlTreeView_FindItem

Пример

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()

    Local $hItem[10], $hItemFound, $htmp_item, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView - Поиск пункта", 400, 300)
    Opt("GUIDataSeparatorChar", "\")

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 3
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 0 To 2
            $htmp_item = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $y), $hItem[$x])
        Next
    Next
    $hItem[4] = GUICtrlCreateTreeViewItem(StringFormat("Посмотрите на меня", $x), $htmp_item)
    For $x = 5 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hItemFound = _GUICtrlTreeView_FindItemEx($hTreeView, "[03] Пункт\[02] Пункт\Посмотрите на меня")
    If $hItemFound Then
        _GUICtrlTreeView_SelectItem($hTreeView, $hItemFound)
        MsgBox(4160, "Информация", "Пункт найден:" & @LF & "Дескриптор: " & $hItemFound & @LF & "Текст: " & _GUICtrlTreeView_GetText($hTreeView, $hItemFound))
    Else
        MsgBox(4160, "Информация", "Не найден")
    EndIf

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main