_GUICtrlTreeView_AddFirst
Добавляет новый пункт в начало списка
#include <GuiTreeView.au3>
_GUICtrlTreeView_AddFirst($hWnd, $hSibling, $sText [, $iImage = -1 [, $iSelImage = -1]])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $hSibling |
Соседний пункт, на уровень которого будет добавлен пункт |
| $sText |
Текст пункта |
| $iImage |
[необязательный] Индекс иконки в списке изображений, отсчёт от 0 |
| $iSelImage |
[необязательный] Индекс иконки в списке изображений, отсчёт от 0 (иконка выбранного пункта) |
Возвращаемое значение
| Успех: | Возвращает дескриптор нового пункта |
| Ошибка: | Возвращает 0 |
Примечания
Пункт добавляется первым к списку по соседству на один и тот же уровень вложения с указанным в параметре $hSibling. Items that appear after the added item are moved down.См. также
_GUICtrlTreeView_AddПример
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hItem, $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("Добавляет пункт в начало", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 1 To Random(2, 10, 1)
$hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] Пункт", $x))
For $y = 1 To Random(2, 10, 1)
_GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] Дочерний", $y))
Next
Next
_GUICtrlTreeView_AddFirst($hTreeView, $hItem, "[00] Первый Пункт")
_GUICtrlTreeView_EndUpdate($hTreeView)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main