Функция _GUICtrlToolbar_SetHotItem

 ↑  ←  Описание функции

_GUICtrlToolbar_SetHotItem

Устанавливает горячую кнопку

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetHotItem($hWnd, $iIndex)

Параметры

$hWnd Дескриптор элемента
$iIndex Индекс кнопки, которая будет горячей. Если -1, то ни одна кнопка не будет горячей.

Возвращаемое значение

Успех: Возвращает индекс предыдущей горячей кнопки, или -1 если таковой не существует.

Примечания

Кнопка считается горячей когда курсор находится над ней

См. также

_GUICtrlToolbar_GetHotItem

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)

    GUISetState()

    ; Добавляет стандартный системный bitmaps
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Делает кнопку горячей
    _GUICtrlToolbar_SetHotItem($hToolbar, 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main