Функция _GUICtrlToolbar_InsertMarkHitTest

 ↑  ←  Описание функции

_GUICtrlToolbar_InsertMarkHitTest

Возвращает информацию о маркере вставки для указанной точки

#include <GuiToolBar.au3>
_GUICtrlToolbar_InsertMarkHitTest($hWnd, $iX, $iY)

Параметры

$hWnd Дескриптор элемента
$iX X-координата относительно клиентской области
$iY Y-координата относительно клиентской области

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Индекс маркера вставки или -1 при его отсутствии, отсчёт от 0
        [1] - Указывает, где находится маркер вставки по отношению к кнопке:
        0 - Слева
        1 - Справа
        2 - На фоне Toolbar

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aStrings[4], $aRect, $aMark
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 46, 396, 252, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет строки
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Новая")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Открыть")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Сохранить")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Справка")

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; Устанавливает маркер вставки
    _GUICtrlToolbar_SetInsertMark($hToolbar, 1, 1)

    ; Делает 1-ый горячий тест маркера вставки
    $aMark = _GUICtrlToolbar_InsertMarkHitTest($hToolbar, 0, 0)
    MemoWrite("Индекс ...: " & $aMark[0])
    MemoWrite("Отношение : " & $aMark[1])

    ; Делает 2-ой горячий тест маркера вставки
    $aRect = _GUICtrlToolbar_GetButtonRect($hToolbar, $idSave)
    $aMark = _GUICtrlToolbar_InsertMarkHitTest($hToolbar, $aRect[0], $aRect[1])
    MemoWrite("Индекс ...: " & $aMark[0])
    MemoWrite("Отношение : " & $aMark[1])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite