_GUICtrlToolbar_HitTest
Определяет, какой элемент Toolbar находится в указанных координатах
#include <GuiToolBar.au3>
_GUICtrlToolbar_HitTest($hWnd, $iX, $iY)
Параметры
| $hWnd | Дескриптор элемента |
| $iX |
Проверяемая X-координата |
| $iY |
Проверяемая Y-координата |
Возвращаемое значение
Успех: Если возвращаемое значение равно 0 или положительное, то это индекс пункта, не являющегося разделителем, отсчёт от 0.Примечания
Абсолютная величина возвращаемого значения является индексом разделителя или ближайший не разделитель.Пример
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar, $aRect, $iHit, $aStrings[4]
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 46, 396, 252, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; Добавляет стандартный системный bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Добавляет строки
$aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Новая")
$aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Открыть")
$aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Сохранить")
$aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Справка")
; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])
; Делает горячий тест на кнопке "Сохранить"
$aRect = _GUICtrlToolbar_GetButtonRect($hToolbar, $idSave)
$iHit = _GUICtrlToolbar_HitTest($hToolbar, $aRect[0], $aRect[1])
MemoWrite(StringFormat("Тест в координатах x=%d, y=%d\r\n\r\nИндекс=%d", $aRect[0], $aRect[1], $iHit))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite