↑  ←  Описание функции

_GUICtrlToolbar_GetButtonInfoEx

Возвращает расширенную информацию кнопки

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonInfoEx($hWnd, $iCommandID)

Параметры

Возвращаемое значение

См. также

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $tButton
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags ($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; Устанавливает информацию кнопки "Save"
    $tButton = DllStructCreate($tagTBBUTTONINFO)
    DllStructSetData($tButton, "Mask", BitOR($TBIF_IMAGE, $TBIF_STATE, $TBIF_SIZE, $TBIF_LPARAM))
    DllStructSetData($tButton, "State", BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED))
    DllStructSetData($tButton, "Image", $STD_PRINT)
    DllStructSetData($tButton, "CX", 100)
    DllStructSetData($tButton, "Param", 1234)
    _GUICtrlToolbar_SetButtonInfoEx ($hToolbar, $idSave, $tButton)

    ; Показывает информацию кнопки "Save"
    $tButton = _GUICtrlToolbar_GetButtonInfoEx ($hToolbar, $idSave)
    MemoWrite("Индекс изображения: " & DllStructGetData($tButton, "Image"))
    MemoWrite("Флаги состояния ..: " & DllStructGetData($tButton, "State"))
    MemoWrite("Ширина кнопки ....: " & DllStructGetData($tButton, "CX"))
    MemoWrite("Ассоциат. значение: " & DllStructGetData($tButton, "Param"))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite