_GUICtrlStatusBar_GetRectEx
Возвращает ограничивающий прямоугольник части
#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetRectEx($hWnd, $iPart)
Параметры
| $hWnd | Дескриптор элемента |
| $iPart |
Индекс части, отсчёт от 0. Если строка состояния в простом режиме, то этот параметр должен быть равен 0. |
Возвращаемое значение
| Успех: | Возвращает структуру $tagRECT, которая содержит ограничивающий прямоугольник |
| Ошибка: | Устанавливает @error |
См. также
_GUICtrlStatusBar_GetRect, $tagRECTПример
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
$Debug_SB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $tRect, $hStatus
Local $aParts[3] = [75, 150, -1]
; Создаёт GUI
$hGUI = GUICreate("StatusBar - Получает прямоугольник (Ex)", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Устанавливает и получает части
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; Получает прямоугольник 1-ой части
$tRect = _GUICtrlStatusBar_GetRectEx ($hStatus, 0)
MemoWrite("Часть 1 слева ...: " & DllStructGetData($tRect, "Left"))
MemoWrite("Часть 1 сверху ..: " & DllStructGetData($tRect, "Top"))
MemoWrite("Часть 1 справа ..: " & DllStructGetData($tRect, "Right"))
MemoWrite("Часть 1 снизу ...: " & DllStructGetData($tRect, "Bottom"))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite