_GUICtrlStatusBar_GetBorders
Возвращает текущую ширину горизонтальной и вертикальной границ
#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetBorders($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | Возвращает массив следующего формата: |
| $aBorders[0] - Ширина горизонтальной границы | |
| $aBorders[1] - Ширина вертикальной границы | |
| $aBorders[2] - Ширина границы между прямоугольниками | |
| Ошибка: | Устанавливает @error |
См. также
_GUICtrlStatusBar_GetBordersHorz, _GUICtrlStatusBar_GetBordersRect, _GUICtrlStatusBar_GetBordersVertПример
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
$Debug_SB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $aInfo, $hStatus
Local $aParts[3] = [75, 150, -1]
; Создаёт GUI
$hGUI = GUICreate("StatusBar - Получает границы", 400, 300)
$hStatus = _GUICtrlStatusBar_Create ($hGUI)
_GUICtrlStatusBar_SetParts ($hStatus, $aParts)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Получает размер границ
$aInfo = _GUICtrlStatusBar_GetBorders ($hStatus)
MemoWrite("Ширина горизонтальной границы: " & $aInfo[0])
MemoWrite("Ширина вертикальной границы..: " & $aInfo[1])
MemoWrite("Ширина между прямоугольниками: " & $aInfo[2])
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite