Функция _GUICtrlMonthCal_SetFirstDOW

         Описание функции

_GUICtrlMonthCal_SetFirstDOW

Устанавливает первый день недели элемента календаря месяца

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetFirstDOW($hWnd, $sDay)

Параметры

$hWnd Дескриптор или идентификатор элемента
$sDay День недели в следующем формате:
    0 или "Monday" (Понедельник)
    1 или "Tuesday" (Вторник)
    2 или "Wednesday" (Среда)
    3 или "Thursday" (Четверг)
    4 или "Friday" (Пятница)
    5 или "Saturday" (Суббота)
    6 или "Sunday" (Воскресенье)

Возвращаемое значение

Успех:Возвращает ранее используемый первый день недели
Ошибка:Возвращает -1

См. также

_GUICtrlMonthCal_GetFirstDOW

Пример

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

$Debug_MC = False ; Проверяет ClassName передаваемый в MonthCal функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hMonthCal

    ; Создаёт GUI
    GUICreate("Устанавливает первый день недели", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Создаёт элемент для заметок
    $iMemo = GUICtrlCreateEdit("", 4, 188, 392, 108, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Установить / получить первый день недели
    _GUICtrlMonthCal_SetFirstDOW($hMonthCal, 0)
    MemoWrite("Первый день недели : " & _GUICtrlMonthCal_GetFirstDOW($hMonthCal))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite