Функция _GUICtrlMonthCal_SetDayState

         Описание функции

_GUICtrlMonthCal_SetDayState

Устанавливает состояние отображения числа дня для всех месяцев, которые в данный момент видимы

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetDayState($hWnd, $aMasks)

Параметры

$hWnd Дескриптор или идентификатор элемента
$aMasks Массив целых чисел соответствующий месяцам, видимых в календаре. Каждое число является битовым флагом.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если вы хотите использовать эту функцию, необходимо создать MonthCal со стилем $MCS_DAYSTATE

Пример

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

$Debug_MC = False ; Проверяет ClassName передаваемый в MonthCal функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hMonthCal

    ; Создаёт GUI
    GUICreate("Устанавливает жирный шрифт дням", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_DAYSTATE), 0x00000000)

    ; Получает количество месяцев, для которых мы должны установить маски. Обычно это число будет 3.
    Local $aMasks[_GUICtrlMonthCal_GetMonthRangeSpan($hMonthCal, True)]

    ; Делает жирными числа 1, 8 и 16 текущего месяца. Это результат битовой маски 1000 0000 1000 0001 или 0x8081 в шестнадцатеричном формате.
    $aMasks[1] = 0x8081
    _GUICtrlMonthCal_SetDayState($hMonthCal, $aMasks)

    GUISetState()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main