Функция _GUICtrlMenu_SetItemData

         Описание функции

_GUICtrlMenu_SetItemData

Устанавливает ассоциативное значение определяемое приложением пункту меню

#include <GuiMenu.au3>
_GUICtrlMenu_SetItemData($hMenu, $iItem, $iData [, $fByPos = True])

Параметры

$hMenu Дескриптор меню
$iItem Идентификатор или позиция пункта меню
$iData Ассоциативное значение определяемое приложением
$fByPos [необязательный] Флаг для идентификации меню:
    True - $iItem является позицией пункта, отсчёт от 0
    False - $iItem является идентификатором пункта

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlMenu_GetItemData

Пример

#include <GuiMenu.au3>

_Main()

Func _Main()
    Local $hWnd, $hMain

    ; Запуск блокнота
    Run("notepad.exe")
    $hWnd = WinWaitActive("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; Установить / получить ассоциативное значение пункта меню "Файл"
    Writeln("Ассоциативное значение: " & _GUICtrlMenu_GetItemData($hMain, 0))
    _GUICtrlMenu_SetItemData($hMain, 0, 1234)
    Writeln("Ассоциативное значение: " & _GUICtrlMenu_GetItemData($hMain, 0))

EndFunc   ;==>_Main

; Записывает строку текста в блокнот
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CR)
EndFunc   ;==>Writeln