Функция _GUICtrlListView_SetItemText

         Описание функции

_GUICtrlListView_SetItemText

Изменить текст пункта или подпункта

#include <GuiListView.au3>
_GUICtrlListView_SetItemText($hWnd, $iIndex, $sText [, $iSubItem = 0])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, отсчёт от 0
$sText Текст пункта или подпункта
$iSubItem [необязательный] Индекс подпункта или 0 для пункта, отсчёт от 1

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

If $iSubItem = -1 row is set

См. также

_GUICtrlListView_GetItemText, _GUICtrlListView_GetItemTextArray, _GUICtrlListView_GetItemTextString, _GUICtrlListView_InsertItem

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("Устанавливает текст пункта", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1")
    _GUICtrlListView_AddItem($hListView, "Пункт 2")
    _GUICtrlListView_AddItem($hListView, "Пункт 3")

    ; Устанавливает текст 2-го пункта
    _GUICtrlListView_SetItemText($hListView, 1, "Новый пункт 2")
    MsgBox(4160, "Информация", "Текст 2-го пункта: " & _GUICtrlListView_GetItemText($hListView, 1))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main