Функция _GUICtrlListView_Scroll

         Описание функции

_GUICtrlListView_Scroll

Прокручивает содержимое ListView ползунком

#include <GuiListView.au3>
_GUICtrlListView_Scroll($hWnd, $iDX, $iDY)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iDX Значение (целое), которое определяет величину горизонтального прокручивания в пикселях.
    Если ListView имеет вид списка, то значение определяет количество колонок для прокручивания
$iDY Значение (целое), которое определяет величину вертикального прокручивания в пикселях

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если ListView имеет вид report, то возможно только вертикальное прокручивание с шагом на целую строку. Таким образом, параметр $iDY будет округлен до ближайшего числа пикселей, которое образует смещение на целое количество строк. Например, если высота строки 16 пикселей, а для $iDY передаётся 8, то список будет прокручиваться на 16 пикселей (1 строка). Если $iDY передаётся 7, то список будет прокручен на 0 пикселей (0 строк).

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView - Прокрутка", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет колонку
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 100
        _GUICtrlListView_AddItem($hListView, "Пункт " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Прокручивает 500 пикселей
    _GUICtrlListView_Scroll($hListView, 0, 500)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main