Функция _GUICtrlListView_Arrange

         Описание функции

_GUICtrlListView_Arrange

Упорядочивает пункты in icon view

#include <GuiListView.au3>
_GUICtrlListView_Arrange($hWnd [, $iArrange = 0])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iArrange [необязательный] Выравнивание. Это может быть одно из следующих значений:
    0 - Выравнивает пункты в зависимости от значений по умолчанию
    1 - Выравнивает пункты вдоль левого края
    2 - Выравнивает пункты вдоль верхнего края
    3 - Упорядочивает все иконки в ближайшую позицию по сетке.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListView_SetItemPosition

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

; Создание GUI
GUICreate("Упорядочивание пунктов ListView", 400, 300)
$iListView = GUICtrlCreateListView("", 2, 2, 394, 268)
$iButton = GUICtrlCreateButton('Упорядочить', 400-120, 300-25, 110, 20)
GUISetState()

; Вставляет колонку
_GUICtrlListView_InsertColumn($iListView, 0, "Заголовок", 100)

 ; Приостанавливает перерисовку
_GUICtrlListView_BeginUpdate($iListView)
; Добавляет пункты
For $i = 1 To 10
    _GUICtrlListView_AddItem($iListView, "Пункт " & $i)
Next
 ; Восстанавливает перерисовку
_GUICtrlListView_EndUpdate($iListView)

; Устанавливает вид списком
_GUICtrlListView_SetView($iListView, 3)
; Перемещает 2-ой пункт
_GUICtrlListView_SetItemPosition($iListView, 1, 100, 100)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $iButton
            _GUICtrlListView_Arrange($iListView, 1) ; 0-3
        Case -3
            Exit
    EndSwitch
WEnd