Функция _GUICtrlListBox_SetTabStops

         Описание функции

_GUICtrlListBox_SetTabStops

Устанавливает позиции табуляции

#include <GuiListBox.au3>
_GUICtrlListBox_SetTabStops($hWnd, $aTabStops)

Параметры

$hWnd Дескриптор или идентификатор элемента
$aTabStops Массив позиций табуляции следующего формата:
    [0] - Количество позиций табуляции в массиве (n)
    [1] - 1-ая позиция табуляции
    [2] - 2-ая позиция табуляции
    [n] - n-ая позиция табуляции

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

The integers in $aTabStops represent the number of quarters of the average character width for the font that is selected into the list box. For example, a tab stop of 4 is placed at 1.0 character units, and a tab stop of 6 is placed at 1.5 average character units. However, if the list box is part of a dialog box, the integers are in dialog template units. The tab stops must be sorted in ascending order; backward tabs are not allowed.

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aTabs[4] = [3, 100, 200, 300], $hListBox

    ; Создаёт GUI
    GUICreate("Устанавливает позиции табуляции", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_USETABSTOPS))
    GUISetState()

    ; Устанавливает позиции табуляции
    _GUICtrlListBox_SetTabStops($hListBox, $aTabs)

    ; Добавляет строку с табуляцией
    _GUICtrlListBox_AddString($hListBox, "Колонка 1" & @TAB & "Колонка 2" & @TAB & "Колонка 3")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main