Функция _GUICtrlListBox_SetItemHeight

         Описание функции

_GUICtrlListBox_SetItemHeight

Устанавливает высоту пунктов в пикселях

#include <GuiListBox.au3>
_GUICtrlListBox_SetItemHeight($hWnd, $iHeight [, $iIndex = 0])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iHeight Высота пунктов в пикселях
$iIndex [необязательный] Индекс пункта, отсчёт от 0. Используйте этот параметр только, если ListBox имеет стиль LBS_OWNERDRAWVARIABLE (разрешает индивидуальную высоту) иначе установите в 0.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlListBox_GetItemHeight

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Устанавливает высоту пунктов", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет строки
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Рандомная строка", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Получает высоту пунктов
    MsgBox(4160, "Информация", "Высота пунктов: " & _GUICtrlListBox_GetItemHeight($hListBox))

    ; Устанавливает высоту пунктов
    _GUICtrlListBox_SetItemHeight($hListBox, 26)

    ; Получает высоту пунктов
    MsgBox(4160, "Информация", "Высота пунктов: " & _GUICtrlListBox_GetItemHeight($hListBox))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main