Функция _GUICtrlListBox_Dir

         Описание функции

_GUICtrlListBox_Dir

Добавляет имена каталогов и файлов

#include <GuiListBox.au3>
_GUICtrlListBox_Dir($hWnd, $sFile [, $iAttributes = 0 [, $fBrackets = True]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sFile Указывает абсолютный путь, относительный путь или имя файла
$iAttributes [необязательный] Атрибуты добавляемых файлов или каталогов:
    $DDL_READWRITE - Включает в себя файлы для чтения и записи без каких-либо дополнительных атрибутов
    $DDL_READONLY - Включает в себя файлы только для чтения
    $DDL_HIDDEN - Включает в себя скрытые файлы
    $DDL_SYSTEM - Включает в себя системные файлы
    $DDL_DIRECTORY - Включает в себя вложенные каталоги
    $DDL_ARCHIVE - Включает в себя архивные файлы
    $DDL_DRIVES - Включает в себя все подключенные (имеющие букву) диски
    $DDL_EXCLUSIVE - Включает в себя только файлы с указанными атрибутами
$fBrackets [необязательный] Разрешает или запрещает отображение квадратных скобок при использовании $DDL_DRIVES

Возвращаемое значение

Успех:Возвращает индекс последнего добавленного пункта, отсчёт от 0.
Ошибка:Возвращает -1

Примечания

Если недостаточно места для добавления новой строки, то возвращается значение $LB_ERRSPACE

См. также

_GUICtrlListBox_InitStorage

Пример

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_LB = False ; Проверяет ClassName передаваемый в ListBox функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hListBox

    ; Создаёт GUI
    GUICreate("Добавляет каталоги и файлы", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет файлы
    _GUICtrlListBox_BeginUpdate($hListBox)
    _GUICtrlListBox_ResetContent($hListBox)
    _GUICtrlListBox_InitStorage($hListBox, 100, 4096)
    _GUICtrlListBox_Dir($hListBox, @WindowsDir & "\win*.exe")
    _GUICtrlListBox_AddFile($hListBox, @WindowsDir & "\Notepad.exe")
    _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES)
    _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES, False)
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main