Описание функции Описание функции
_GUICtrlIpAddress_Create
Создаёт элемент GUI IP Address
#include <GuiIPAddress.au3>
_GUICtrlIpAddress_Create($hWnd, $iX, $iY [, $iWidth = 125 [, $iHeight = 25 [, $iStyles = 0x00000000 [, $iExstyles = 0x00000000]]]])
Параметры
| $hWnd | Дескриптор родительского окна или окна владельца |
| $iX |
X координата элемента |
| $iY |
Y координата элемента |
| $iWidth |
[необязательный] Ширина элемента |
| $iHeight |
[необязательный] Высота элемента |
| $iStyles |
[необязательный] Стиль элемента: Принудительно : $WS_CHILD, $WS_VISIBLE, $WS_TABSTOP |
| $iExStyles |
[необязательный] Расширенный стиль элемента |
Возвращаемое значение
| Успех: | Возвращает дескриптор элемента IP Address |
| Ошибка: | Возвращает 0 |
См. также
_GUICtrlIpAddress_DestroyПример
#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>
$Debug_IP = False ; Проверяет ClassName передаваемый в IPAddress функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $hIPAddress
_Main()
Func _Main()
Local $hgui
$hgui = GUICreate("Пример создания IP Address", 400, 300)
$hIPAddress = _GUICtrlIpAddress_Create ($hgui, 10, 10)
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
_GUICtrlIpAddress_Set ($hIPAddress, "24.168.2.128")
; Цикл, ожидающий закрытия GUI-окна
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
#forceref $hWnd, $iMsg, $iwParam
Local $hWndFrom, $iCode, $tNMHDR ; , $iIDFrom
Local $tInfo
$tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
; $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
$iCode = DllStructGetData($tNMHDR, "Code")
Switch $hWndFrom
Case $hIPAddress
Switch $iCode
Case $IPN_FIELDCHANGED ; Высылается, когда пользователь изменяет поля в элементе управления или перемещает курсор из одного поля в другое
$tInfo = DllStructCreate($tagNMIPADDRESS, $ilParam)
_DebugPrint("$IPN_FIELDCHANGED" & @LF & "--> hWndFrom:" & @TAB & DllStructGetData($tInfo, "hWndFrom") & @LF & _
"-->IDFrom:" & @TAB & DllStructGetData($tInfo, "IDFrom") & @LF & _
"-->Code:" & @TAB & DllStructGetData($tInfo, "Code") & @LF & _
"-->Field:" & @TAB & DllStructGetData($tInfo, "Field") & @LF & _
"-->Value:" & @TAB & DllStructGetData($tInfo, "Value"))
; The return value is ignored
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_NOTIFY
Func _DebugPrint($s_text, $line = @ScriptLineNumber)
ConsoleWrite( _
"!===========================================================" & @LF & _
"+======================================================" & @LF & _
"-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
"+======================================================" & @LF)
EndFunc ;==>_DebugPrint