Функция _GUICtrlEdit_SetReadOnly

         Описание функции

_GUICtrlEdit_SetReadOnly

Устанавливает или удаляет стиль "только чтение" ($ES_READONLY)

#include <GuiEdit.au3>
_GUICtrlEdit_SetReadOnly($hWnd, $fReadOnly)

Параметры

$hWnd Дескриптор или идентификатор элемента
$fReadOnly Следующие значения:
    True - Устанавливает стиль $ES_READONLY
    False - Удаляет стиль $ES_READONLY

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Пример

#include <GuiEdit.au3>
#include <GUIConstantsEx.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

    ; Создаёт GUI
    $hGUI = GUICreate("Только чтение", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    GUISetState()

    ; Добавляет текст
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; Устанавливает состояние "только чтение"
    _GUICtrlEdit_SetReadOnly($hEdit, True)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main