Функция _GUICtrlEdit_SetMargins

         Описание функции

_GUICtrlEdit_SetMargins

Устанавливает ширину левого и правого отступа

#include <GuiEdit.au3>
_GUICtrlEdit_SetMargins($hWnd [, $iMargin = 0x1 [, $iLeft = 0xFFFF [, $iRight = 0xFFFF]]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iMargin [необязательный] Это может быть одно или несколько из следующих значений:
    $EC_LEFTMARGIN - Устанавливает левый отступ
    $EC_RIGHTMARGIN - Устанавливает правый отступ
    По умолчанию: $EC_LEFTMARGIN
$iLeft [необязательный] Новая ширина левого отступа
    По умолчанию: $EC_USEFONTINFO
$iRight [необязательный] Новая ширина правого отступа
    По умолчанию: $EC_USEFONTINFO

Возвращаемое значение

Возвращает массив следующего формата:
[0] - ширина левого отступа
[1] - ширина правого отступа

См. также

_GUICtrlEdit_GetMargins

Пример

#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[2] = [190, -1], $aMargins

    ; Создаёт GUI
    $hGUI = GUICreate("Устанавливает отступ", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    GUISetState()

    ; Установка отступов
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; Устанавливает текст
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; Получает отступы
    $aMargins = _GUICtrlEdit_GetMargins($hEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Левый отступ: " & $aMargins[0])
    _GUICtrlStatusBar_SetText($hStatusBar, "Правый отступ: " & $aMargins[1], 1)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main