Функция _GUICtrlEdit_GetRECT

         Описание функции

_GUICtrlEdit_GetRECT

Возвращает координаты прямоугольника окна редактирования

#include <GuiEdit.au3>
_GUICtrlEdit_GetRECT($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех: Возвращает массив, содержащий координаты в следующем формате:

    [0] - X координата левого верхнего угла прямоугольника
    [1] - Y координата левого верхнего угла прямоугольника
    [2] - X координата правого нижнего угла прямоугольника
    [3] - Y координата правого нижнего угла прямоугольника

Примечания

При определенных условиях, _GUICtrlEdit_GetRECT не может возвратить точные значения, которые установлены функцией _GUICtrlEdit_SetRECT... Это может быть приблизительно скорректировано, но различаться на несколько пикселей.

См. также

_GUICtrlEdit_GetRECTEx

Пример

#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[5] = [1, 85, 180, 285, -1], $aRect

    ; Создаёт GUI
    $hGUI = GUICreate("Получает прямоугольник", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    GUISetState()

    ; Получает прямоугольник
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    $aRect[0] += 10
    $aRect[1] += 10
    $aRect[2] -= 10
    $aRect[3] -= 10

    ; Добавляет текст
    _GUICtrlEdit_AppendText($hEdit, FileRead($sFile))

    ; Устанавливает прямоугольник
    _GUICtrlEdit_SetRECT($hEdit, $aRect)

    ; Получает прямоугольник
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Левый: " & $aRect[0], 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Верхний: " & $aRect[1], 2)
    _GUICtrlStatusBar_SetText($hStatusBar, "Правый: " & $aRect[2], 3)
    _GUICtrlStatusBar_SetText($hStatusBar, "Нижний: " & $aRect[3], 4)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main