Функция _GUICtrlEdit_GetLine

         Описание функции

_GUICtrlEdit_GetLine

Возвращает текстовую строку окна редактирования

#include <GuiEdit.au3>
_GUICtrlEdit_GetLine($hWnd, $iLine)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iLine Индекс строки (отсчёт от 0)

Возвращаемое значение

Успех:Возвращает строку текста
Ошибка:Возвращает пустую строку

Примечания

Если установлен стиль - перенос строк, то количество символов возвращаемой текстовой строки может иметь другое значение при изменении размера окна редактирования.

Пример

#include <GuiEdit.au3>
#include <GUIConstantsEx.au3>

$Debug_Ed = False ; Проверяет ClassName передаваемый в Edit функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hEdit
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

    ; Создаёт GUI
    GUICreate("Получает строку", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
    GUISetState()

    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    MsgBox(4160, "Информация", "Текст строки с индексом 2: " & _GUICtrlEdit_GetLine($hEdit, 2))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main