Функция _GUICtrlComboBoxEx_GetListArray

         Описание функции

_GUICtrlComboBoxEx_GetListArray

Возвращает все пункты из списка ComboBox в виде массива

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetListArray($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Количество пунктов
        [1] - Пункт 1
        [2] - Пункт 2
        [n] - Пункт n

См. также

_GUICtrlComboBoxEx_GetList

Пример

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $aItem, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Получает все пункты в массив", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет диски
    _GUICtrlComboBoxEx_AddDir ($hCombo, "", $DDL_DRIVES, False)

    ; Получает все пункты из списка в массив
    $aItem = _GUICtrlComboBoxEx_GetListArray ($hCombo)

    For $x = 1 To $aItem[0]
        MemoWrite($aItem[$x])
    Next


    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite