Функция _GUICtrlComboBoxEx_GetDroppedControlRect

         Описание функции

_GUICtrlComboBoxEx_GetDroppedControlRect

Возвращает экранные координаты прямоугольника выпадающего списка ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetDroppedControlRect($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - X-координата левого верхнего угла прямоугольника
        [1] - Y-координата левого верхнего угла прямоугольника
        [2] - X-координата правого нижнего угла прямоугольника
        [3] - Y-координата правого нижнего угла прямоугольника

См. также

_GUICtrlComboBoxEx_GetDroppedControlRectEx

Пример

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $aRect, $hCombo

    ; Создаёт GUI
    $hGUI = GUICreate("Получает прямоугольник выпадающего списка", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create ($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    ; Добавляет файлы, диски
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    _GUICtrlComboBoxEx_AddDir ($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBoxEx_AddDir ($hCombo, "", $DDL_DRIVES)
    _GUICtrlComboBoxEx_BeginUpdate ($hCombo)
    _GUICtrlComboBoxEx_AddDir ($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)
    _GUICtrlComboBoxEx_EndUpdate ($hCombo)

    ; Получает прямоугольник выпадающего списка
    $aRect = _GUICtrlComboBoxEx_GetDroppedControlRect ($hCombo)
    MsgBox(4160, "Информация", "Прямоугольник выпадающего списка: " & StringFormat("[%d][%d][%d][%d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main