Функция _GUICtrlComboBox_SetTopIndex

         Описание функции

_GUICtrlComboBox_SetTopIndex

Обеспечивает, чтобы указанный пункт находился в видимой области списка ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetTopIndex($hWnd, $iIndex)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта, отсчёт от 0.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Система прокручивает содержимое списка так, чтобы указанный пункт оказался наверху видимой части списка или максимально прокручивает, чтобы достигнуть этого.

См. также

_GUICtrlComboBox_GetTopIndex

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Устанавливает верхний пункт", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Устанавливает индекс верхнего пункта
    _GUICtrlComboBox_SetTopIndex($hCombo, 10)

    ; Получает верхний пункт
    MsgBox(4160, "Информация", "Индекс верхнего пункта:" & @TAB & _GUICtrlComboBox_GetTopIndex($hCombo))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main