Функция _GUICtrlComboBox_SetHorizontalExtent

         Описание функции

_GUICtrlComboBox_SetHorizontalExtent

Устанавливает ширину в пикселях, в которой можно прокручивать список горизонтально

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetHorizontalExtent($hWnd, $iWidth)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iWidth Ширина в пикселях, для прокручивания списка

Примечания

Если ширина списка меньше, чем $iWidth, то элемент горизонтальный прокрутки горизонтально прокручивает пункты в списке.

Если ширина списка равна или превышает $iWidth, то элемент прокрутки скрыт. Или, если ComboBox при этом имеет стиль $CBS_DISABLENOSCROLL, то элемент прокрутки не скрыт, но недоступен.

См. также

_GUICtrlComboBox_GetHorizontalExtent

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Устанавливает горизонтальную протяжённость списка", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_HSCROLL))
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Получает горизонтальную протяжённость списка
    MsgBox(4160, "Информация", "Горизонтальная протяжённость: " & _GUICtrlComboBox_GetHorizontalExtent($hCombo))

    ; Устанавливает горизонтальную протяжённость списка
    _GUICtrlComboBox_SetHorizontalExtent($hCombo, 500)

    ; Получает горизонтальную протяжённость списка
    MsgBox(4160, "Информация", "Горизонтальная протяжённость: " & _GUICtrlComboBox_GetHorizontalExtent($hCombo))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main