Функция _GUICtrlComboBox_SelectString

         Описание функции

_GUICtrlComboBox_SelectString

Ищет пункт в списке ComboBox, который начинается с символов в указанной строке

#include <GuiComboBox.au3>
_GUICtrlComboBox_SelectString($hWnd, $sText [, $iIndex = -1])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Строка содержащая символы для поиска
$iIndex [необязательный] Индекс пункта, предшествующий пункту с которого начинается поиск. Отсчёт от 0.

Возвращаемое значение

Успех:Возвращает индекс выделенного пункта
Ошибка:Возвращает -1

Примечания

Если поиск достигает конца списка, то продолжается с начала списка до пункта, определяемого параметром wParam.

Если $iIndex = -1, то поиск выполняется по всему списку с самого начала.
Пункт будет выбран, только если вся строка $sText совпадает с текстом пункта от начала (не обязательно до конца).

Если совпадение с пунктом найдено, то пункт будет выбран и скопирован в поле ввода.

См. также

_GUICtrlComboBox_FindString, _GUICtrlComboBox_FindStringExact, _GUICtrlComboBoxEx_FindStringExact

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Ищет пункт в списке и выделяет её", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    ; Добавляет строку
    _GUICtrlComboBox_AddString($hCombo, "Эта строка была добавлена")
    ; Добавляет диски
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Ищет пункт в списке и выделяет её
    _GUICtrlComboBox_SelectString($hCombo, "Эта")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main