Функция _GUICtrlComboBox_InitStorage

         Описание функции

_GUICtrlComboBox_InitStorage

Выделяет память для хранения пунктов в списке ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_InitStorage($hWnd, $iNum, $iBytes)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iNum Количество добавляемых пунктов
$iBytes Объем памяти, выделенной для пункта, в байтах

Возвращаемое значение

Успех:Общее количество пунктов, для которых была предварительно выделена память
Ошибка:$CB_ERRSPACE

Примечания

Помогает ускорить инициализацию ComboBoxes, который имеет большое количество пунктов (более 100).

Для оценки вы можете использовать параметры $iNum и $iBytes.
Если выделено сверх меры, то дополнительная память выделяется.
Если выделено недостаточно, то используется обычное выделение памяти для пунктов, которые превышают требуемое количество.

См. также

_GUICtrlComboBox_AddDir, _GUICtrlComboBox_AddString, _GUICtrlComboBox_InsertString

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Выделяет память", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; Выделяет память
    MsgBox(4160, "Информация", "Выделяет память для: " & _GUICtrlComboBox_InitStorage($hCombo, 50, 500) & " пунктов")

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main