Функция _GUICtrlComboBox_GetMinVisible

         Описание функции

_GUICtrlComboBox_GetMinVisible

Возвращает минимальное количество видимых строк в раскрывающемся списке ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetMinVisible($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Успех:Возвращает минимальное количество видимых строк
Ошибка:Возвращает False

Примечания

Если количество строк в раскрывающемся списке больше, чем минимум, то в ComboBox появляется полоса прокрутки.

Эта функция игнорируется, если ComboBox имеет стиль $CBS_NOINTEGRALHEIGHT

См. также

_GUICtrlComboBox_SetMinVisible

Пример

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ; Проверяет ClassName передаваемый в ComboBox/ComboBoxEx функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hCombo

    ; Создаёт GUI
    GUICreate("Получает минимально видимых", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState()

    ; Добавляет файлы
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Получает минимально видимых
    MsgBox(4160, "Информация", "Минимально видимых:" & @TAB & _GUICtrlComboBox_GetMinVisible($hCombo), 3)

    ; Раскрывает список
    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; Устанавливает минимально видимых
    _GUICtrlComboBox_SetMinVisible($hCombo, 50)

    ; Сворачивает список
    _GUICtrlComboBox_ShowDropDown($hCombo)

    Sleep(500)

    ; Раскрывает список
    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; Получает минимально видимых
    MsgBox(4160, "Информация", "Минимально видимых:" & @TAB & _GUICtrlComboBox_GetMinVisible($hCombo), 3)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main