Функция _ExcelHorizontalAlignSet

_ExcelHorizontalAlignSet

Устанавливает параметр "горизонтальное выравнивание" для всех ячеек целевого диапазона.

#include <Excel.au3>
_ExcelHorizontalAlignSet($oExcel, $sRangeOrRowStart [, $iColStart = 1 [, $iRowEnd = 1 [, $iColEnd = 1 [, $sHorizAlign = "left"]]]])

Параметры

$oExcel	Ссылка на COM-объект "Excel.Application" полученная ранее вызванными _ExcelBookOpen(), _ExcelBookNew(), или _ExcelBookAttach() Внимание!!! Метод использует условные координаты диапазона - координаты верхней левой и нижней правой ячеек (формат ссылок R1C1) Следующие 4 параметра описывают координаты этих ячеек:
$sRangeOrRowStart	Номер строки верхней левой ячейки целевого диапазона
$iColStart	[необязательный]Номер столбца верхней левой ячейки целевого диапазона (по умолчанию=1)
$iRowEnd	[необязательный]Номер строки нижней правой ячейки целевого диапазона (по умолчанию=1)
$iColEnd	[необязательный]Номер столбца нижней правой ячейки целевого диапазона(по умолчанию=1)
$sHorizAlign	[необязательный] Тип горизонтального выравнивания "left"\|"center"\|"right" ; {по левому краю\|по центру\|по правому краю} соответственно(по умолчанию="left")

Возвращаемое значение

Успех:	Возвращает 1
Ошибка:	Возвращает 0, Устанавливает значение флага ошибки @error:
@error:	0 - Скрипт завершил работу без ошибок
	1 - Ошибка OLE/COM ($oExcel), возможно указанный объект не существует
	2 - Значение строки\столбца верхней левой ячейки целевого диапазона не является числом, или недопустимо
	3 - Значение строки\столбца нижней правой ячейки целевого диапазона не является числом, или недопустимо
@extended:	0 - Ошибка в значении строки
	1 - Ошибка в значении столбца

Примечания

Внимание!!! документы разных форматов MS Office Excel имеют различные ограничения по количеству столбцов и строк:
*.xls (формат xlExcel8, стандартный для MS Office 2003,97,95) имеет ограничения в 255 столбцов 65 535 строк
*.xlsx,*.xlsb,*.xlsm (XML-форматы MS Office 2007-2010) имеют ограничения в 16 384 столбца и 1 048 576 строк

Пример

; ***************************************
; Пример 1 - Изменение параметра горизонтального выравнивания у всех ячеек целевого диапазона
; ***************************************

#include <Excel.au3>

Local $oExcel = _ExcelBookNew() ;Создает новую рабочую книгу
Local $sRangeOrRowStart = 1, $iColStart = 1, $iRowEnd = 10, $iColEnd = 10, $sHorizAlign = "left"

; Циклически заполняем диапазон ячеек случайными числами
For $i = 1 To 10
For $j = 1 To 10
_ExcelWriteCell($oExcel, Round(Random(1, 100), 0), $i, $j) ;Записывает в ячейку случайное целое число из диапазона от 1 до 100
Next
Next

MsgBox(4096, "_ExcelHorizontalAlignSet", "Демонстрация вариантов горизонтального выравнивания" & @CRLF & "Нажмите ОК для продолжения")

_ExcelHorizontalAlignSet($oExcel, $sRangeOrRowStart, $iColStart, $iRowEnd, $iColEnd, $sHorizAlign)
ToolTip("Горизонтальное выравнивание 'по левому краю'")
Sleep(2000) ; Пауза 2 сек.

$sHorizAlign = "center"
_ExcelHorizontalAlignSet($oExcel, $sRangeOrRowStart, $iColStart, $iRowEnd, $iColEnd, $sHorizAlign)
ToolTip("Горизонтальное выравнивание 'по центру'")
Sleep(2000) ; Пауза 2 сек.

$sHorizAlign = "right"
_ExcelHorizontalAlignSet($oExcel, $sRangeOrRowStart, $iColStart, $iRowEnd, $iColEnd, $sHorizAlign)
ToolTip("Горизонтальное выравнивание 'по правому краю'")
Sleep(2000) ; Пауза 2 сек.

MsgBox(4096, "_ExcelHorizontalAlignSet | Пример 1", "Демонстрация завершена, нажмите ОК")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; Сохраняем файл в директории временных файлов, перезаписывая если необходимо.
_ExcelBookClose($oExcel) ; Закрываем рабочую книгу