Функция

Функция _DateAdd

_DateAdd

Вычисляет новую дату, добавляя к исходной дате промежуток времени.

#include <Date.au3>
_DateAdd($sType, $iValToAdd, $sDate)

Параметры

$sType	одно из следующих значений: D - добавляет количество дней к дате M - добавляет количество месяцев к дате Y - добавляет количество лет к дате w - добавляет количество недель к дате h - добавляет количество часов к дате n - добавляет количество минут к дате s - добавляет количество секунд к дате
$iValToAdd	Добавляемое число
$sDate	Исходная дата в формате YYYY/MM/DD[ HH:MM:SS]

Возвращаемое значение

Успех:	Возвращает новую дату, полученную в результате добавления.
Ошибка:	Возвращает 0 и устанавливает @error
@error:	0 - нет ошибок
	1 - неверный $sType
	2 - неверный $iValToAdd
	3 - неверный $sDate

Примечания

Функция не возвращает неверную дату.
При добавлении трёх месяцев к дате '2004/1/31', результатом будет '2004/04/30'.

См. также

_DateDiff, _DateTimeSplit, _DateToDayOfWeek, _DateToDayOfWeekISO, _DateToDayValue, _DayValueToDate

Пример

#include <Date.au3>

; Добавит 5 дней к сегодняшнему дню
$sNewDate = _DateAdd( 'd',5, _NowCalcDate())
MsgBox( 4096, "", "Сегодня + 5 дней:" & $sNewDate )

; Вычтет 2 недели из сегодняшнего дня
$sNewDate = _DateAdd( 'w',-2, _NowCalcDate())
MsgBox( 4096, "", "Сегодня минус 2 недели: " & $sNewDate )

; Добавит 15 минут к текущему времени
$sNewDate = _DateAdd( 'n',15, _NowCalc())
MsgBox( 4096, "", "Текущее время +15 минут: " & $sNewDate )

; Вычислит дату лога событий, который хранит секунды с 1970/01/01 00:00:00
$sNewDate = _DateAdd( 's',1087497645, "1970/01/01 00:00:00")
MsgBox( 4096, "", "Дата: " & $sNewDate )