Функция _Date_Time_SystemTimeToArray

         Описание функции

_Date_Time_SystemTimeToArray

Декодирует системное время в массив

#include <Date.au3>
_Date_Time_SystemTimeToArray(ByRef $tSystemTime)

Параметры

$tSystemTime Структура $tagSYSTEMTIME

Возвращаемое значение

Возвращает массив следующего формата:
    [0] - Месяц
    [1] - День
    [2] - Год
    [3] - Час
    [4] - Минуты
    [5] - Секунды
    [6] - Миллисекунды
    [7] - День недели

См. также

$tagSYSTEMTIME

Пример

#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $tTime, $aTime

    ; Создаёт GUI
    $hGUI = GUICreate("Время", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Получение текущего системного времени
    $tTime = _Date_Time_GetSystemTime()
    $aTime = _Date_Time_SystemTimeToArray($tTime)
    MemoWrite("Месяц .......: " & $aTime[0])
    MemoWrite("День ........: " & $aTime[1])
    MemoWrite("Год .........: " & $aTime[2])
    MemoWrite("Час .........: " & $aTime[3])
    MemoWrite("Минута ......: " & $aTime[4])
    MemoWrite("Секунда .....: " & $aTime[5])
    MemoWrite("Миллисекунда : " & $aTime[6])
    MemoWrite("День недели .: " & $aTime[7])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite